[fezh]

No.

#include <amxmodx>
#include <fakemeta>

new Trie:g_tEntities;
new g_hSpawn;

public plugin_precache( )
{
    new const szEntities[ ][ ] =
    {    
        "func_hostage_rescue",
        "info_hostage_rescue",
        "func_bomb_target",
        "info_bomb_target",
        "hostage_entity",
        "info_vip_start",
        "func_vip_safetyzone",
        "func_escapezone"
    };
    
    g_tEntities = TrieCreate( );
    
    for ( new i = 0; i < sizeof( szEntities ); i++ )
    {
        TrieSetCell( g_tEntities, szEntities[ i ], i );
    }
    
    g_hSpawn = register_forward( FM_Spawn, "Fwd_Spawn_Pre", 0 );
}

public Fwd_Spawn_Pre( iEnt )
{
    static szClassName[ 21 ];
    pev( iEnt, pev_classname, szClassName, charsmax( szClassName ) );
    
    if ( TrieKeyExists( g_tEntities, szClassName ) )
    {
        engfunc( EngFunc_RemoveEntity, iEnt );
        return FMRES_SUPERCEDE;
    }
    return FMRES_IGNORED;
}

public plugin_init( )
{
    unregister_forward( FM_Spawn, g_hSpawn );
    
    TrieDestroy( g_tEntities );
}